빈곤을 측정하는 가장 대표적인 지표로는 절대빈곤율과 상대빈곤율이 사용된다. 빈곤율을 산출하는 기준은 연구자에 따라서 다르겠지만, 노동패널 기초분석보고서에서 사용한 절대빈곤율 및 상대빈곤율의 개념을 소개하면 다음과 같다.

절대빈곤율은 보건복지부에서 매년 발표하는 가구원 수별 기초생계비를 기준으로 그 이하의 소득을 얻고 있는 가구를 빈곤선 이하의 가구로 정하여 계산한다. 또한 절대빈곤율 계산에서의 차상위계층이란 빈곤선의 120%의 소득에 해당하는 구간을 의미한다.

한편 상대빈곤율은 가구총소득이 중위소득의 50% 이하에 속하는 계층을 의미하며, 차상위계층은 중위소득의 50~70%에 속하는 계층을 말한다

아래는 SAS를 이용한 빈곤율 산출프로그램 예제이다. SPSS 프로그램은 생략한다.

*=============================;
*   (SAS문) 빈곤가구 구하기   ;
*=============================;
/*-----------빈곤가구 구하기----------*/

data a2; set a1(keep=hhid inc v09100 hwave09);
if inc=0 then inc=.;
if inc=. then delete;

incm=inc/12; /* 월소득 */
fnum=v09100;
if fnum > 6 then fnum=6;  /* 가구원 수가 6이상이면 전부 6으로 간주 */
if hwave09=1 then do;
  if fnum=1 & 0 < incm < 36.8 then pov=1;  /*빈곤층*/
 else  if fnum=2 & incm < 61.0 then pov=1;      /* 보건복지부 지정 빈곤 Definition */
 else  if fnum=3 & incm < 83.9 then pov=1;
 else  if fnum=4 & incm < 105.5 then pov=1;
 else  if fnum=5 & incm < 120.0 then pov=1;
 else  if fnum=6 & incm < 135.4 then pov=1;

 else  if fnum=1 & 35.6 <= incm < (36.8*1.2) then pov=2;  /*차상위*/
 else  if fnum=2 & 58.9 <= incm < (61.0*1.2) then pov=2;
 else  if fnum=3 & 81.0 <= incm < (83.9*1.2) then pov=2;
 else  if fnum=4 & 101.9 <= incm < (105.5*1.2) then pov=2;
 else  if fnum=5 & 115.9 <= incm < (120.0*1.2) then pov=2;
 else  if fnum=6 & 130.8 <= incm < (135.4*1.2) then pov=2;
else pov=0;
end;

proc sort; by hhid; run;
proc freq; table pov; run;

/*-----------상대빈곤가구 구하기----------*/

data a3; set a1(keep=hhid inc v09100 hwave09);
if inc=0 then inc=.;
if inc=. then delete;
fnum=v09100;
flag=1;
incr=inc/sqrt(fnum);
proc sort; by hhid; run;
proc means noprint; where hwave09=1; var incr;
output out=a4 median=incrmd;
run;

data a4; set a4;
flag=1;
run;

/* (Note) a3는 가구수만큼 케이스가 많은 데이터셋이고, a4는 means 프로시저의 결과값중 incr의 중위수만 들어가 있는, 케이스 한개짜리 데이터셋이다. a3의 각 케이스마다 동일한 incrmd가 붙어있는 a5 라는 데이터셋을 만들기 위해서는, 위와 같이 a3, a4 에다가 flag 라는 가변수를 포함시킨 뒤, 아래와 같이 merge by 문을 이용하면 된다. */

data a5; merge a3 a4; by flag;
if hwave09=1 then do;
   if incr < (incrmd*0.5)  then rpo=1; /*빈곤*/
 else  if incr < (incrmd*0.7)  then rpo=2; /*차상위*/
 else  if incr < (incrmd*1.5)  then rpo=3; /*중산층*/
 else  rpo=4; /*상위*/
end;

proc sort; by hhid; run;
proc freq; table rpo; run;